nixcfg/modules/home/tools/git/default.nix

{ lib, config, pkgs, ... }:

let
  inherit (lib) types mkEnableOption mkIf;
  inherit (lib.metacfg) mkOpt enabled;

  cfg = config.metacfg.tools.git;
  user = config.metacfg.user;
in
{
  options.metacfg.tools.git = {
    enable = mkEnableOption "Git";
    userName = mkOpt types.str user.fullName "The name to configure git with.";
    userEmail = mkOpt types.str user.email "The email to configure git with.";
    signingKey =
      mkOpt types.str "7F3D64824AC0B6B8009E50504BC0896FB5693595" "The key ID to sign commits with.";
    signByDefault = mkOpt types.bool false "Whether to sign commits by default.";
  };

  config = mkIf cfg.enable {
    home.packages = with pkgs; [
      git-delete-merged-branches
      delta
    ];
    programs.git = {
      enable = true;
      inherit (cfg) userName userEmail;
      lfs = enabled;
      signing = {
        key = cfg.signingKey;
        inherit (cfg) signByDefault;
      };
      extraConfig = {
        init = { defaultBranch = "main"; };
        pull = { rebase = true; };
        push = { autoSetupRemote = true; };
        core = { whitespace = "trailing-space,space-before-tab"; };
        safe = {
          directory = "${user.home}/git";
        };
        "credential \"https://github.com\"" = {
          helper = "!gh auth git-credential";
        };
        alias = {
          co = "checkout";
          ci = "commit --signoff";
        };
        pull.ff = "only";
        core.pager = "${pkgs.delta}/bin/delta";
        delta = {
          features = "decorations";
          syntax-theme = "DarkNeon";
          light = "false";
          navigate = "true";
        };
        interactive.diffFilter = "${pkgs.delta}/bin/delta --color-only";
        merge.conflictStyle = "diff3";
        diff.colorMoved = "default";
        filter.rot8000 = {
          clean = "${pkgs.metacfg.rot8000}/bin/rot8000";
          smudge = "${pkgs.metacfg.rot8000}/bin/rot8000";
        };
        http.sslCAinfo = "/etc/ssl/certs/ca-certificates.crt";
      };
    };
  };
}