{ channels, ... }:
final: prev: {
  inherit (channels.unstable)
    gemini-cli
    opencode
    tailscale
    mistral-vibe
    claude-code
    qwen-code
    # llama-cpp-rocm
    # open-webui
    # vscode
    # nodejs_20
    ;

  # Tuned for Strix Halo (Ryzen AI Max+ 395 / Radeon 8060S, gfx1151).
  llama-cpp-rocm =
    (channels.unstable.llama-cpp.override {
      rocmSupport = true;
      rocmGpuTargets = [ "gfx1151" ];
    }).overrideAttrs
      (prevAttrs: {
        src = prev.fetchFromGitHub {
          owner = "am17an";
          repo = "llama.cpp";
          rev = "9a532ae4bab1b164052ce60a738f78538b421c66";
          hash = "sha256-LIGtXaO53Y3Ze0x6uevb2vzcKHbyj2o/8ZHvyZ22uo4=";
          #postFetch = ''
          #  echo -n "9a532ae4bab1b164052ce60a738f78538b421c66" > $out/COMMIT
          #'';
        };
        npmDepsHash = "sha256-Po5SWJv3vmcBR7y62G9/CfvI3Lk/MYdjFMTTy2dsgoY=";
        npmRoot = "tools/ui";
      });

  geekbench_6 = channels.unstable.geekbench_6.overrideAttrs (prevAttrs: rec {
    version = "6.7.0";
    src = prev.fetchurl (
      {
        "x86_64-linux" = {
          url = "https://cdn.geekbench.com/Geekbench-${version}-Linux.tar.gz";
          hash = "sha256-Snt3179Re/zwxop1pvzWF39TXXi8ZUBlNWB+v7+YE38=";
        };
        "aarch64-linux" = {
          url = "https://cdn.geekbench.com/Geekbench-${version}-LinuxARMPreview.tar.gz";
          hash = "sha256-GCAOKYyijaQPVBgAixoZRPHIdiUfV8mPeeflE7aX8Ac=";
        };
      }
      .${prev.stdenv.system} or (throw "unsupported system ${prev.stdenv.hostPlatform.system}")
    );
  });
}