Harald Hoyer
c9c7f6916a
rocwmma is header-only and ships no CMake config file, so find_package(rocwmma) is not available. hipcc/clang also bypass the nixpkgs cc-wrapper that would normally pick up headers from buildInputs, so the rocwmma path was unreachable and the build failed with: ggml-cuda/vendors/hip.h: 'rocwmma/rocwmma-version.hpp' file not found Inject -I<rocwmma>/include via CMAKE_HIP_FLAGS (HIP TUs) and CMAKE_CXX_FLAGS (C++ TUs that include hip.h transitively).
78 lines
2.6 KiB
Nix
78 lines
2.6 KiB
Nix
{ channels, ... }:
|
|
final: prev: {
|
|
inherit (channels.unstable)
|
|
gemini-cli
|
|
opencode
|
|
tailscale
|
|
# claude-code
|
|
qwen-code
|
|
# llama-cpp-rocm
|
|
# open-webui
|
|
# vscode
|
|
# nodejs_20
|
|
;
|
|
|
|
# Tuned for Strix Halo (Ryzen AI Max+ 395 / Radeon 8060S, gfx1151).
|
|
llama-cpp-rocm =
|
|
(channels.unstable.llama-cpp.override {
|
|
rocmSupport = true;
|
|
rocmGpuTargets = [ "gfx1151" ];
|
|
}).overrideAttrs
|
|
(prevAttrs: {
|
|
src = prev.fetchFromGitHub {
|
|
owner = "am17an";
|
|
repo = "llama.cpp";
|
|
rev = "267f8afe857b7bd1a49e4fde9138ab0f7be36625";
|
|
hash = "sha256-VYvRjnNZpPE60wjpBVO1FbURMRRMg71sM5kBxiEkElk=";
|
|
postFetch = ''
|
|
echo -n "267f8af" > $out/COMMIT
|
|
'';
|
|
};
|
|
npmDepsHash = "sha256-k62LIbyY2DXvs7XXbX0lNPiYxuYzeJUyQtS4eA+68f8=";
|
|
|
|
buildInputs = (prevAttrs.buildInputs or [ ]) ++ [
|
|
channels.unstable.rocmPackages.rocwmma
|
|
];
|
|
|
|
# rocwmma is header-only and ships no CMake config; hipcc/clang
|
|
# bypass the cc-wrapper, so inject the include path directly.
|
|
cmakeFlags = (prevAttrs.cmakeFlags or [ ]) ++ [
|
|
"-DGGML_HIP_ROCWMMA_FATTN=ON"
|
|
"-DGGML_HIP_GRAPHS=ON"
|
|
"-DCMAKE_HIP_FLAGS=-I${channels.unstable.rocmPackages.rocwmma}/include"
|
|
"-DCMAKE_CXX_FLAGS=-I${channels.unstable.rocmPackages.rocwmma}/include"
|
|
];
|
|
});
|
|
|
|
/*
|
|
gnome-remote-desktop = channels.unstable.gnome-remote-desktop.overrideAttrs (prevAttrs: {
|
|
patches = (prevAttrs.patches or [ ]) ++ [
|
|
./gnome-remote-desktop-mac.patch
|
|
];
|
|
});
|
|
*/
|
|
|
|
# goose-cli = channels.unstable.callPackage ./goose.nix { };
|
|
claude-code = channels.unstable.callPackage ./claude-code/package.nix { };
|
|
|
|
geekbench_6 = channels.unstable.geekbench_6.overrideAttrs (prevAttrs: rec {
|
|
version = "6.7.0";
|
|
src = prev.fetchurl (
|
|
{
|
|
"x86_64-linux" = {
|
|
url = "https://cdn.geekbench.com/Geekbench-${version}-Linux.tar.gz";
|
|
hash = "sha256-Snt3179Re/zwxop1pvzWF39TXXi8ZUBlNWB+v7+YE38=";
|
|
};
|
|
"aarch64-linux" = {
|
|
url = "https://cdn.geekbench.com/Geekbench-${version}-LinuxARMPreview.tar.gz";
|
|
hash = "sha256-GCAOKYyijaQPVBgAixoZRPHIdiUfV8mPeeflE7aX8Ac=";
|
|
};
|
|
}
|
|
.${prev.stdenv.system} or (throw "unsupported system ${prev.stdenv.hostPlatform.system}")
|
|
);
|
|
});
|
|
# gemini-cli = channels.unstable.callPackage ./gemini-cli/package.nix { };
|
|
# vscode-extensions = channels.unstable.vscode-extensions // {
|
|
# rooveterinaryinc = { roo-cline = channels.unstable.callPackage ./roo-code.nix { }; };
|
|
# };
|
|
}
|