Harald Hoyer
f62e8ac470
- Restrict rocmGpuTargets to gfx1151 (Radeon 8060S, RDNA 3.5) — smaller closure, faster compile, no wasted device kernels. - Enable GGML_HIP_ROCWMMA_FATTN: rocWMMA-backed flash attention is a major win on RDNA3+ for the GPU-offloaded attention path. - Enable GGML_HIP_GRAPHS to lower per-token launch overhead. - Add rocwmma to buildInputs to satisfy the WMMA path. llama-server on halo runs with -ngl 99 --flash-attn on, so these flags target the hot path. CPU-side AVX-512 was skipped intentionally — Zen 5 has it, but with full GPU offload the CPU paths barely run.
74 lines
2.3 KiB
Nix
74 lines
2.3 KiB
Nix
{ channels, ... }:
|
|
final: prev: {
|
|
inherit (channels.unstable)
|
|
gemini-cli
|
|
opencode
|
|
tailscale
|
|
# claude-code
|
|
qwen-code
|
|
# llama-cpp-rocm
|
|
# open-webui
|
|
# vscode
|
|
# nodejs_20
|
|
;
|
|
|
|
# Tuned for Strix Halo (Ryzen AI Max+ 395 / Radeon 8060S, gfx1151).
|
|
llama-cpp-rocm =
|
|
(channels.unstable.llama-cpp.override {
|
|
rocmSupport = true;
|
|
rocmGpuTargets = [ "gfx1151" ];
|
|
}).overrideAttrs
|
|
(prevAttrs: {
|
|
src = prev.fetchFromGitHub {
|
|
owner = "am17an";
|
|
repo = "llama.cpp";
|
|
rev = "267f8afe857b7bd1a49e4fde9138ab0f7be36625";
|
|
hash = "sha256-VYvRjnNZpPE60wjpBVO1FbURMRRMg71sM5kBxiEkElk=";
|
|
postFetch = ''
|
|
echo -n "267f8af" > $out/COMMIT
|
|
'';
|
|
};
|
|
npmDepsHash = "sha256-k62LIbyY2DXvs7XXbX0lNPiYxuYzeJUyQtS4eA+68f8=";
|
|
|
|
buildInputs = (prevAttrs.buildInputs or [ ]) ++ [
|
|
channels.unstable.rocmPackages.rocwmma
|
|
];
|
|
|
|
cmakeFlags = (prevAttrs.cmakeFlags or [ ]) ++ [
|
|
"-DGGML_HIP_ROCWMMA_FATTN=ON"
|
|
"-DGGML_HIP_GRAPHS=ON"
|
|
];
|
|
});
|
|
|
|
/*
|
|
gnome-remote-desktop = channels.unstable.gnome-remote-desktop.overrideAttrs (prevAttrs: {
|
|
patches = (prevAttrs.patches or [ ]) ++ [
|
|
./gnome-remote-desktop-mac.patch
|
|
];
|
|
});
|
|
*/
|
|
|
|
# goose-cli = channels.unstable.callPackage ./goose.nix { };
|
|
claude-code = channels.unstable.callPackage ./claude-code/package.nix { };
|
|
|
|
geekbench_6 = channels.unstable.geekbench_6.overrideAttrs (prevAttrs: rec {
|
|
version = "6.7.0";
|
|
src = prev.fetchurl (
|
|
{
|
|
"x86_64-linux" = {
|
|
url = "https://cdn.geekbench.com/Geekbench-${version}-Linux.tar.gz";
|
|
hash = "sha256-Snt3179Re/zwxop1pvzWF39TXXi8ZUBlNWB+v7+YE38=";
|
|
};
|
|
"aarch64-linux" = {
|
|
url = "https://cdn.geekbench.com/Geekbench-${version}-LinuxARMPreview.tar.gz";
|
|
hash = "sha256-GCAOKYyijaQPVBgAixoZRPHIdiUfV8mPeeflE7aX8Ac=";
|
|
};
|
|
}
|
|
.${prev.stdenv.system} or (throw "unsupported system ${prev.stdenv.hostPlatform.system}")
|
|
);
|
|
});
|
|
# gemini-cli = channels.unstable.callPackage ./gemini-cli/package.nix { };
|
|
# vscode-extensions = channels.unstable.vscode-extensions // {
|
|
# rooveterinaryinc = { roo-cline = channels.unstable.callPackage ./roo-code.nix { }; };
|
|
# };
|
|
}
|