{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs, ... }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
    in
    {
      packages = forAllSystems (pkgs: {
        default = pkgs.callPackage ./wyoming-whisper-rs/package.nix { src = self; };
      });

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          nativeBuildInputs = [
            pkgs.rustc
            pkgs.cargo
            pkgs.clippy
            pkgs.rustfmt
            pkgs.cmake
            pkgs.pkg-config
            pkgs.shaderc
            pkgs.rocmPackages.llvm.clang
          ];

          buildInputs = [
            pkgs.libclang.lib
            pkgs.openssl
            pkgs.vulkan-headers
            pkgs.vulkan-loader
            pkgs.rocmPackages.clr
            pkgs.rocmPackages.hipblas
            pkgs.rocmPackages.rocblas
            pkgs.rocmPackages.rocm-runtime
          ];

          env = {
            LIBCLANG_PATH = "${pkgs.libclang.lib}/lib";
            VULKAN_SDK = "${pkgs.vulkan-headers}";
            HIP_PATH = "${pkgs.rocmPackages.clr}";
            BINDGEN_EXTRA_CLANG_ARGS = builtins.toString [
              "-isystem ${pkgs.libclang.lib}/lib/clang/${pkgs.lib.versions.major pkgs.libclang.version}/include"
              "-isystem ${pkgs.glibc.dev}/include"
            ];
          };

          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath [
            pkgs.vulkan-loader
            pkgs.rocmPackages.clr
            pkgs.rocmPackages.hipblas
            pkgs.rocmPackages.rocblas
            pkgs.rocmPackages.rocm-runtime
          ];
        };
      });
    };
}